[Arduino] DIY窮人版的日光自動感應捲簾

每年夏天的早上都會被無情的陽光給剌醒，很不甘願的爬起來拉下窗簾，然後繼續爬回去睡，但這樣總是覺得很麻煩，於是發揮Maker的精神，自己來DIY一個自動感應日光的遮陽捲簾，也可以按下手動鍵，改成手動控制捲簾上升或下降，準備材料如下

光線感應器（其實就是光敏電阻啦）

 捲簾的馬達（360度的伺服馬達）

 不想要的arduino lenonardo（難用）

紅外線反射感應器（也叫循跡感應器）裝在下方當成捲簾下降的極限位置

窗子中間放光線感應器用來感應白天或晚上

上方的紅外線感應器，裝在上方當成捲簾上升的極限位置

控制器部份

5V/2A電源模組

手動控制按鍵

程式如下
#include <Servo.h>
#define DownIRsensor 6         //下降的極限位置(紅外線感應pin腳)
#define UpIRsensor 4           //上升的極限位置(紅外線感應pin腳)
#define DayNightSensor 7       //光敏電阻信號讀取腳位
#define AutoManual 8           //Auto=0, Manual=1
#define ManualUp 11            //手動上升捲簾
#define ManualDown 10         //手動下降捲簾

Servo myservo;


bool debug = 1;
bool AutoFlag = 1;  //AutoFlag = 0代表手動, AutoFlag = 1代表自動

unsigned char action_times = 0xFF;
unsigned char last_action_times = action_times;
bool ManualUpPressed = 0, ManualDownPressed = 0;

void setup() {
  pinMode(DownIRsensor, INPUT);
  pinMode(UpIRsensor, INPUT);
  pinMode(AutoManual, INPUT);             //Auto=0, Manual=1
  pinMode(DayNightSensor, INPUT);
  digitalWrite(DayNightSensor, HIGH);
  pinMode(ManualUp, INPUT);
  pinMode(ManualDown, INPUT);
  pinMode(13, OUTPUT);
  Serial.begin(9600);
}

void loop() {

  if (AutoFlag) {
    if (digitalRead(AutoManual) == 0) {
      action_times = 0x01;
    }
    else if (digitalRead(DayNightSensor) == 0) { //代表白天
      action_times = 0x04;
    }
    else if (digitalRead(DayNightSensor) == 1) { //代表晚上
      action_times = 0x05;
      }
    else {
      action_times = 0xFF;
    }
  }
  else {
    if (digitalRead(AutoManual) == 0) {
      action_times = 0x01;
    }
    else if (digitalRead(ManualUp) == 0 && ManualDownPressed == 0) {    //捲簾上升
      action_times = 0x02;
    }
    else if (digitalRead(ManualDown) == 0 && ManualUpPressed == 0) {    //捲簾下降
      action_times = 0x03;
    }
    else {
      action_times = 0xFF;
    }
  }

  if (action_times != last_action_times) {
    last_action_times = action_times;
    if (action_times == 0x01) {                         //手動或自動
      AutoFlag = !AutoFlag;
      if (AutoFlag) {
        myservo.detach();
        ManualUpPressed = 0;
        ManualDownPressed = 0;
        digitalWrite(13, LOW);
        if (debug) {
          Serial.println("Switch to Auto Mode");
        }
      }
      else {
        digitalWrite(13, HIGH);
        if (debug) {
          Serial.println("Switch to Manual Mode");
        }
      }
    }
    else if (action_times == 0x02) {            //手動上升按鍵程序
      ManualUpPressed = !ManualUpPressed;
      if (ManualUpPressed) {
        myservo.attach(9);                       //連接servo
        myservo.write(180);                      //捲簾上升
        if (debug) {
          Serial.println("Electric Shutter is going up...");
        }
      }
      else {
        myservo.detach();
        if (debug) {
          Serial.println("Electric Shutter is stop");
        }
      }
    }
    else if (action_times == 0x03) {            //手動下降按鍵程序
      ManualDownPressed = !ManualDownPressed;
      if (ManualDownPressed) {
        myservo.attach(9);                       //連接servo
        myservo.write(0);                        //捲簾下降
        if (debug) {
          Serial.println("Electric Shutter is going down...");
          delay(500);
        }
      }
      else {
        myservo.detach();
        if (debug) {
          Serial.println("Electric Shutter is stop");
     
        }
      }
    }
    else if (action_times == 0x04) {              //白天處理程序
      if (debug) {
        Serial.println("Now is day...");
      }
      if (digitalRead(DownIRsensor) == 1) {
        myservo.attach(9);                       //連接servo
        myservo.write(0);                        //捲簾下降
        do {
          if (debug) {
           Serial.println("Electric Shutter is going down...");
       
          }
        } while (digitalRead(DownIRsensor) == 1);
      }
      if (debug) {
        Serial.println("down Electric Shutter is stop...");
      }
      myservo.detach();
    } // EOF- 0x04
    else if (action_times == 0x05) {              //晚上處理程序
      if (debug) {
        Serial.println("Now is night...");
      }
      if (digitalRead(UpIRsensor) == 0) {
        myservo.attach(9);                    
        myservo.write(180);                  
        do {
          if (debug) {                      
            Serial.println("Electric Shutter is going up...");
         
          }
        } while (digitalRead(UpIRsensor) == 0);
      }
      if (debug) {
        Serial.println("Up Electric Shutter is stop...");
      }
   
      myservo.detach();
    } // EOF- 0x05
  }

} // EOF- Loop

實際操作影片